La tecla Bloq Mayús ocupa el espacio principal del teclado y no está haciendo todo lo posible. Este sencillo script de AutoHotkey convertirá el bloqueo de mayúsculas en una tecla modificadora para que puedas usarlo para accesos directos personalizables.

Los basicos

Esta secuencia de comandos le permitirá presionar Bloq Mayús + G para buscar rápidamente texto en Google desde cualquier lugar de Windows o presionar Bloq Mayús + D para buscar la definición de diccionario de una palabra. Estos atajos son personalizables, por supuesto.

Lo mejor de todo es que este guión inteligente aún te permite usar Bloq Mayús normalmente. Puede activar y desactivar el bloqueo de mayúsculas presionándolo rápidamente dos veces. Si no lo hace, el bloqueo de mayúsculas funcionará como una tecla modificadora para los atajos.

AutoHotkey 101

AutoHotkey es una aplicación gratuita de Windows que se encuentra en segundo plano y ejecuta scripts. Puede escribir estos scripts usted mismo o descargarlos. Los scripts generalmente esperan una pulsación de tecla y realizan una acción. De esta manera, AutoHotkey es una forma rápida de reasignar claves en Windows o asignar diferentes acciones a las teclas.

Por ejemplo, hemos mostrado cómo puede usar AutoHotkey para deshabilitar la tecla de Windows, evitando que abra el menú Inicio y lo saque de los juegos de PC de pantalla completa. No es necesario levantar la tapa del teclado.

  Evite que Windows se ponga en suspensión cuando Chrome está descargando archivos

Instale AutoHotkey y obtenga el script

Descarga AutoHotkey e instálelo para comenzar. A continuación, descargue el script CapsLock Modifier.

Extraiga el archivo de script AHK del archivo ZIP y colóquelo en cualquier carpeta de su computadora. Para ejecutarlo con AutoHotkey, haga clic con el botón derecho en el script y seleccione «Ejecutar script».

Ejecutando un script de AutoHotkey desde el Explorador de archivos.

El script ahora se está ejecutando en segundo plano. Para activar y desactivar el bloqueo de mayúsculas, toque dos veces rápidamente la tecla Bloq Mayús.

Si no presiona dos veces, el bloqueo de mayúsculas solo funciona como una tecla modificadora. Con las funciones integradas en el script, puede utilizar los siguientes atajos en cualquier lugar de Windows:

Presione Bloq Mayús + d para encontrar la definición de diccionario de una palabra seleccionada.
Presione Bloq Mayús + g para buscar en Google el texto seleccionado en cualquier lugar de Windows.
Presione Bloq Mayús + t para buscar la palabra seleccionada en un diccionario de sinónimos.
Presione Bloq Mayús + w para buscar el texto seleccionado en Wikipedia.

¿Quieres más atajos? Puede crear el suyo propio con un poco de conocimiento de los scripts de AutoHotkey.

Para controlar AutoHotkey, busque el icono de AutoHotkey en su área de notificación; tiene un fondo verde con una H blanca. Para dejar de ejecutar el script, simplemente haga clic con el botón derecho en el icono de AutoHotkey y seleccione «Salir».

Salir de AutoHotkey y finalizar un script.

¿Como funciona?

Si desea ver qué hace la secuencia de comandos, haga clic con el botón derecho y seleccione «Editar secuencia de comandos». Esto abrirá el script en el Bloc de notas y podrá examinar su código. El guión es bastante breve y fácil de entender. Recomendamos no descargar y ejecutar scripts extraños sin antes mirarlos y comprenderlos.

  Cómo obtener el nuevo lanzador de Microsoft similar a Spotlight en Windows 10

Este guión nos lo envió Dave Kellog. Aquí está la parte mágica del script que hace que el bloqueo de mayúsculas funcione como una tecla modificadora si se presiona dos veces:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Este bit espera a ver si se presiona el Bloq Mayús dos veces y lo activa o desactiva. De lo contrario, el script captura el bloqueo de mayúsculas y lo usa para atajos de modificadores.

El resto del script contiene las acciones de acceso directo y una útil función de portapapeles que guarda el contenido de su portapapeles y lo restaura. Esa parte es bastante necesaria, ya que las funciones de modificación utilizan el portapapeles para realizar acciones en el texto seleccionado.

¿Quiere ver el guión completo sin descargarlo? Aquí está:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Hemos visto scripts de AutoHotkey que convierten el bloqueo de mayúsculas en una tecla modificadora antes, pero nunca uno que mantenga el bloqueo de mayúsculas como una palanca si lo presiona dos veces. Es muy inteligente. Gracias nuevamente a Dave Kellog por enviárnoslo.

  Cómo iniciar dual Linux y Windows 10